Como funciona o sensor indutivo e como conectar com Arduino

Um dos sensores mais utilizados em automação industrial e projetos de robótica é o sensor de proximidade indutivo, capaz de identificar quando um objeto metálico se aproxima de uma determinada posição. Para quem deseja entender como funciona o sensor indutivo, basta saber que ele detecta a presença de metais sem contato físico, tornando-se ideal para aplicações como detecção de fim de curso (quando uma parte móvel atinge o limite do seu deslocamento) e contagem de peças em movimento (quando passam na frente do sensor).

Existem diferentes tecnologias para sensores de proximidade, cada uma com vantagens e desvantagens. Neste artigo, vamos explicar o que é e como funciona o sensor indutivo, mostrar seus principais tipos (2 fios, 3 fios, 4 fios, PNP e NPN) e apresentar um exemplo prático de conexão com Arduino, usando o modelo LJ12A3-4-Z/BX disponível na nossa loja.

O que é um sensor indutivo?

O sensor indutivo é um dispositivo eletrônico usado para detectar a presença ou a aproximação de objetos metálicos, sem contato físico. Ele faz parte da família dos sensores de proximidade, que identificam quando algo está perto sem precisar tocar no objeto.

Este sensor funciona a partir do princípio da indução eletromagnética, onde um campo magnético gerado por uma bobina dentro do sensor interage com objetos metálicos próximos, alterando as características desse campo e permitindo a detecção.

Por ser robusto, sem partes móveis e resistente a poeira e sujeira (desde que não metálica), o sensor indutivo é muito utilizado em automação industrial, controle de máquinas e sistemas de segurança.

Como funciona o sensor indutivo?

Como o próprio nome indica, o sensor indutivo funciona com base no fenômeno da indução eletromagnética. Quando um objeto metálico é exposto a um campo magnético variável, pequenas correntes elétricas, chamadas de correntes induzidas, são geradas nesse objeto.

Dentro do sensor, há um circuito oscilador formado por um capacitor e uma bobina enrolada em um núcleo de ferrite. Essa bobina cria o campo magnético. Quando um metal entra nesse campo, parte da energia é absorvida, reduzindo a amplitude do sinal do oscilador.

O sinal do oscilador é então enviado para um circuito Schmitt Trigger. Esse tipo de circuito altera o estado da saída (alto ou baixo) de acordo com o nível do sinal recebido. A característica especial do Schmitt Trigger é a histerese, ou seja, o ponto de mudança para “ligar” é diferente do ponto para “desligar”. Isso evita que a saída oscile rapidamente quando o sinal fica próximo do valor limite de detecção.

Em resumo:

A bobina cria um campo magnético.
Um metal se aproxima → correntes induzidas consomem parte da energia.
O sinal diminui → Schmitt Trigger detecta a mudança.
A saída do sensor muda de estado, indicando a presença do objeto.

Tipos de sensor indutivo

Existem diversos tipos de sensores de proximidade indutivos, que variam tanto no formato quanto no modo de conexão ao sistema de automação. Eles podem ser classificados de acordo com o tipo de corrente utilizada (CA ou CC) e pela quantidade de fios.

Sensores indutivos CA (Corrente Alternada)

Funcionam como interruptores acionados pela aproximação de um objeto metálico.
Possuem 2 fios e são ligados em série com o dispositivo a ser controlado.
Podem ser:
- NA (Normalmente Aberto) – a carga é ligada quando o metal está próximo.
- NF (Normalmente Fechado) – a carga é desligada quando o metal está próximo.

Sensores indutivos CC (Corrente Contínua)

Estão disponíveis em versões com 2 fios, 3 fios ou 4 fios:

Sensor indutivo 2 fios: instalados como os modelos CA, em série com a carga.
Sensor indutivo 3 fios: recebem alimentação CC em um fio e fornecem a saída em outro.
Sensor indutivo 4 fios: semelhantes aos de 3 fios, mas com terras da alimentação e da saída separados.

A saída dos sensores CC é feita por um transistor, resultando em dois subtipos:

Sensor indutivo NPN: a saída fica desconectada ou conectada ao GND.
Sensor indutivo PNP: a saída fica desconectada ou conectada ao VCC (alimentação).

Resumo do tipos de sensor indutivo

Tipo de Sensor	Nº de fios	Tipo de saída	Característica principal
CA 2 fios NA	2	AC	Liga carga quando detecta metal
CA 2 fios NF	2	AC	Desliga carga quando detecta metal
CC 2 fios	2	DC	Instalação simples, como AC
CC 3 fios NPN	3	NPN	Saída ligada ao GND
CC 3 fios PNP	3	PNP	Saída ligada ao VCC
CC 4 fios NPN	4	NPN	Terras separados
CC 4 fios PNP	4	PNP	Terras separados

Sensor Indutivo LJ12A3-4-Z/BX

O LJ12A3-4-Z/BX é um sensor indutivo NPN de proximidade com três fios, ideal para uso em projetos com microcontroladores, como o Arduino. Ele requer alimentação de 6 a 36 V CC e suporta até 300 mA de corrente na saída. Este modelo é capaz de detectar objetos metálicos a uma distância de até 4 mm.

Identificação dos fios:

GND (fio azul): conectar ao terra (GND) da fonte de alimentação e ao GND do microcontrolador.
SINAL (fio preto): conectar a um pino digital do microcontrolador.
VCC (fio marrom): conectar à alimentação positiva da fonte externa (6–36 V CC).

Dica: Sempre confira a pinagem na ficha técnica antes da instalação para evitar danos ao sensor ou ao microcontrolador. Clique aqui para ver o Sensor Indutivo LJ12A3-4-Z/BX na loja

Vantagens e desvantagens do sensor indutivo

O sensor indutivo apresenta diversas vantagens que o tornam uma excelente opção para detecção de objetos metálicos em ambientes industriais e projetos de automação:

Vantagens

Alta durabilidade: não possui partes móveis, o que aumenta a vida útil.
Imune à luz ambiente: não sofre interferência de fontes luminosas.
Resistência à poeira: pode operar em ambientes com poeira não metálica.
Alta precisão: garante detecção confiável em curtas distâncias.

Por outro lado, é importante considerar algumas limitações do sensor indutivo:

Desvantagens

Somente para metais: não detecta materiais não metálicos.
Alcance limitado: a distância de detecção é relativamente pequena (geralmente de poucos milímetros).

Como conectar o sensor indutivo com Arduino?

Antes de conectar o sensor indutivo ao Arduino, é importante entender que o modelo LJ12A3-4-Z/BX requer uma alimentação entre 6 e 36 volts, uma tensão que normalmente não está disponível diretamente no Arduino.

Você pode alimentar o sensor de duas formas:

Usar uma fonte de alimentação externa separada para o sensor;
Alimentar o Arduino com uma fonte de 9V conectada na entrada Vin e alimentar o sensor a partir desse ponto.

Conexão do sensor NPN ao Arduino

O sensor NPN tem uma saída que funciona como um transistor que conecta o pino de saída ao terra (GND) quando detecta metal. Para usar essa saída com o Arduino, você precisa:

Conectar o fio azul do sensor ao GND do Arduino.
Conectar o fio marrom do sensor à fonte de alimentação (6–36 V).
Conectar o fio preto do sensor a um pino digital do Arduino (exemplo: pino 2).
Usar um resistor de pull-up no pino digital do Arduino para garantir que o sinal fique em nível alto quando o sensor não detecta objeto. Você pode usar o resistor interno do Arduino ativando o pull-up via software (com pinMode(pino, INPUT_PULLUP)).

Quando o sensor não detecta objeto, a saída estará em nível alto (devido ao resistor pull-up). Quando detectar, o transistor NPN conecta a saída ao GND, deixando o sinal em nível baixo.

Cuidados com sensores PNP e de dois fios

Se o seu sensor for do tipo PNP (saída conecta ao positivo) ou dois fios (alimentação e saída no mesmo fio), é preciso tomar precauções para não danificar o Arduino. Nesses casos, o ideal é usar um acoplador óptico para isolar a saída do sensor do microcontrolador, evitando a passagem de tensões indesejadas.

O lado do software

Do ponto de vista do software no Arduino, o sensor indutivo funciona como uma entrada digital comum. O circuito interno do sensor, com o Schmitt Trigger, ajuda a estabilizar o sinal, reduzindo a necessidade de implementar um debounce no código, na maioria dos casos.

Interpretação dos níveis lógicos:

Quando o sensor detecta um objeto metálico, a saída estará em nível baixo (LOW).
Quando não há detecção, a saída estará em nível alto (HIGH), devido ao resistor pull-up no Arduino.

Dica importante: Apesar do Schmitt Trigger minimizar oscilações, em ambientes com muita interferência eletromagnética pode ser necessário implementar um debounce no código para garantir leituras estáveis.

Exemplo completo: medindo rotações de motor com sensor indutivo e Arduino

Neste exemplo, vamos usar o sensor indutivo LJ12A3-4-Z/BX para medir as rotações por minuto (RPM) de um motor de passo 28BYJ-48 com driver ULN2003.

As especificações do sensor indicam uma taxa máxima de detecção de 50 Hz, o que corresponde a até 3000 RPM. Para demonstração, vamos variar aleatoriamente a velocidade do motor entre 5 e 20 RPM a cada minuto, dentro do limite do motor de passo.

Os dados da medição serão enviados ao Monitor Serial da IDE Arduino para visualização em tempo real.

Componentes necessários

Montagem do circuito

Para facilitar, alimente o Arduino com a fonte de 9V e use o resistor de pull-up interno para o pino digital conectado ao sensor.

Na montagem, utilize um pedaço de fio preso ao eixo do motor para acionar o sensor. Outra opção é fixar um pequeno objeto metálico em um círculo não metálico preso ao eixo, posicionando o sensor para que o objeto metálico passe a cerca de 2 ou 3 mm dele.

Código

// Controle Motor de Passo
#define N_PASSOS 2048L  // número de passos por volta
const int pinoMotor[4] = { A0, A1, A2, A3 };
const int nivelPasso[4][4] = { {1,0,0,1}, {1,1,0,0}, {0,1,1,0}, {0,0,1,1} };

// Sensor
const int pinoSensor = 2;

// Iniciação
void setup() {
  Serial.begin(115200);
  Serial.println("\nDemonstracao Sensor Indutivo");
  for (int i = 0; i < 4; i++) {
    pinMode(pinoMotor[i], OUTPUT);
  }
  pinMode(pinoSensor, INPUT_PULLUP);
}

// Loop Principal
void loop() {
  static unsigned long tmpMudanca = millis();
  static unsigned long tmpSensor = 0;
  static int sensorAnt = HIGH;
  static unsigned int delayPasso = 2000;
  static int passo = 0;

  // Trata o sensor
  int sensor = digitalRead(pinoSensor);
  if (sensor != sensorAnt) {
    sensorAnt = sensor;
    if (sensor == LOW) {
      // Detectou objeto
      if (tmpSensor != 0) {
        unsigned long tempo = millis() - tmpSensor;
        double rpm = 60000.0/tempo;
        Serial.print ("Tempo: ");
        Serial.print (tempo);
        Serial.print ("  ");
        Serial.print (rpm,1);
        Serial.println (" RPM");
      }
    } else {
      // Objeto se afastou
      tmpSensor = millis();
    }
  }

  // Determina velocidade do motor
  if (millis() >= tmpMudanca) {
    // Muda aleatoriamente a velocidade
    int rpm = random(5, 21);
    delayPasso = 60000000L / (rpm*N_PASSOS);
    printRPM(delayPasso);
    tmpMudanca = millis() + 60000UL;
  }

  // Avança um passo
  for (int i = 0; i < 4; i++) {
    digitalWrite(pinoMotor[i], nivelPasso[passo][i]);
  }
  delayMicroseconds(delayPasso);
  passo = (passo+1) & 3;
}

// Mostra a velocidade programada para o motor
void printRPM(unsigned int dly) {
  // etapas por minuto
  unsigned long passos = 60000000L / dly;
  unsigned long rpm = passos / N_PASSOS;
  Serial.print("Delay: ");
  Serial.print(dly);
  Serial.print(" Freq: ");
  Serial.print(1000000L / dly);
  Serial.print("Hz Passos: ");
  Serial.print(passos);
  Serial.print(" RPM: ");
  Serial.println(rpm);
}

// Controle Motor de Passo

#define N_PASSOS 2048L // número de passos por volta

const int pinoMotor[4] = { A0, A1, A2, A3 };

const int nivelPasso[4][4] = { {1,0,0,1}, {1,1,0,0}, {0,1,1,0}, {0,0,1,1} };

// Sensor

const int pinoSensor = 2;

// Iniciação

void setup() {

Serial.begin(115200);

Serial.println("\nDemonstracao Sensor Indutivo");

for (int i = 0; i < 4; i++) {

pinMode(pinoMotor[i], OUTPUT);

}

pinMode(pinoSensor, INPUT_PULLUP);

}

// Loop Principal

void loop() {

static unsigned long tmpMudanca = millis();

static unsigned long tmpSensor = 0;

static int sensorAnt = HIGH;

static unsigned int delayPasso = 2000;

static int passo = 0;

// Trata o sensor

int sensor = digitalRead(pinoSensor);

if (sensor != sensorAnt) {

sensorAnt = sensor;

if (sensor == LOW) {

// Detectou objeto

if (tmpSensor != 0) {

unsigned long tempo = millis() - tmpSensor;

double rpm = 60000.0/tempo;

Serial.print ("Tempo: ");

Serial.print (tempo);

Serial.print (" ");

Serial.print (rpm,1);

Serial.println (" RPM");

}

} else {

// Objeto se afastou

tmpSensor = millis();

}

// Determina velocidade do motor

if (millis() >= tmpMudanca) {

// Muda aleatoriamente a velocidade

int rpm = random(5, 21);

delayPasso = 60000000L / (rpm*N_PASSOS);

printRPM(delayPasso);

tmpMudanca = millis() + 60000UL;

}

// Avança um passo

for (int i = 0; i < 4; i++) {

digitalWrite(pinoMotor[i], nivelPasso[passo][i]);

}

delayMicroseconds(delayPasso);

passo = (passo+1) & 3;

}

// Mostra a velocidade programada para o motor

void printRPM(unsigned int dly) {

// etapas por minuto

unsigned long passos = 60000000L / dly;

unsigned long rpm = passos / N_PASSOS;

Serial.print("Delay: ");

Serial.print(dly);

Serial.print(" Freq: ");

Serial.print(1000000L / dly);

Serial.print("Hz Passos: ");

Serial.print(passos);

Serial.print(" RPM: ");

Serial.println(rpm);

}

Funcionamento

Quando o objeto metálico preso ao eixo passar pelo sensor, o sinal digital mudará, permitindo contar as rotações do motor. A partir da frequência dessas mudanças, calculamos as RPM do motor em tempo real.

Você pode conferir o funcionamento deste projeto no vídeo:

Você pode observar o funcionamento do sensor no Monitor Serial da IDE Arduino:

Conclusão

O sensor de proximidade indutivo é uma solução eficiente e confiável para projetos que precisam detectar a passagem ou aproximação de objetos metálicos, especialmente em ambientes industriais. Sua interface com microcontroladores é simples e direta, principalmente nos modelos CC com saída NPN, facilitando a integração em sistemas automatizados.

Gostou de aprender como funciona o sensor indutivo? Você já usou ou pretende usar este sensor em seus projetos? Deixe seu comentário e compartilhe sua experiência conosco e não esqueça de seguir a gente no Instagram!

Como funciona o sensor indutivo e como conectar com Arduino Deixe um comentário